ao

Ao Volume

前言
需要准备的材料
制作流程

前言

本项目基于开源项目deej:https://github.com/omriharel/deej
在次项目中用修改后的单片机代码与外壳均已开源:https://github.com/DylanAo/AHU-AI-Repository
你可以在仓库中->专业选修课->人机交互技术中找到

需要准备的材料

Arduion 单片机
电位器 * 3
1寸OLED屏
杜邦线若干
外壳(有就行，自己3D打印或手工制作)
面包板
制作流程

借助面包板与杜邦线连接好VCC与GND、显示屏,并分别将三个电位器输出接入A0、A1、A2

将下面代码复制到arduino IDE中(或者直接使用我开源仓库中.ion文件),选定单片机，注意此时的串口号(接下来会用到)，然后烧录程序
注意:你需要事先安装Adafruit_SSD1306库

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#define OLED_RESET     4

const int NUM_SLIDERS = 3;
const int analogInputs[NUM_SLIDERS] = {A0, A1, A2};
int analogSliderValues[NUM_SLIDERS];

Adafruit_SSD1306 display(128, 64, &Wire,OLED_RESET);
void setup() { 
for (int i = 0; i < NUM_SLIDERS; i++) {
    pinMode(analogInputs[i], INPUT);
}

Serial.begin(9600);
OLED_init(); 
}

void loop() {
updateSliderValues();
sendSliderValues(); // Actually send data (all the time)
delay(10);
OLED_refresh();
}

void updateSliderValues() {
for (int i = 0; i < NUM_SLIDERS; i++) {
    analogSliderValues[i] = analogRead(analogInputs[i]);
}
}

void sendSliderValues() {
String builtString = String("");

for (int i = 0; i < NUM_SLIDERS; i++) {
    builtString += String((int)analogSliderValues[i]);

    if (i < NUM_SLIDERS - 1) {
    builtString += String("|");
    }
}

Serial.println(builtString);
}

void printSliderValues() {
for (int i = 0; i < NUM_SLIDERS; i++) {
    String printedString = String("Slider #") + String(i + 1) + String(": ") + String(analogSliderValues[i]) + String(" mV");
    Serial.write(printedString.c_str());

    if (i < NUM_SLIDERS - 1) {
    Serial.write(" | ");
    } else {
    Serial.write("\n");
    }
}
}

void OLED_refresh() {
display.clearDisplay();
display.setTextSize(1);
display.setCursor(25, 5);
display.println("-Ao Volume-");
display.setCursor(0, 20);
display.println("master:");
display.setCursor(0, 30);
display.println("chat:");
display.setCursor(0, 40);
display.println("game:");
display.setTextSize(1); 
display.setCursor(40, 20);
display.println((int)(analogSliderValues[0] / 10.23));
display.setCursor(30, 30);
display.println((int)(analogSliderValues[1] / 10.23));
display.setCursor(30, 40);
display.println((int)(analogSliderValues[2] / 10.23));
display.display();
}

void OLED_init(){
display.begin(SSD1306_SWITCHCAPVCC,0x3C);
display.setTextColor(WHITE);
display.clearDisplay();
display.setTextSize(1);  
display.setCursor(17, 5);
display.println("-Ao Volume-");
display.setCursor(0, 20);
display.println("master:");
display.setCursor(0, 30);
display.println("chat:");
display.setCursor(0, 40);
display.println("game:");

display.display();
}

关闭arduino IDE(不能留后台)，在原开源仓库中下载deej.exe，并在deej.exe同一目录下创建config.yaml文件，将以下内容复制到config.yaml文件中并保存
注意:你要根据步骤2中看到的串口号修改文件中com_port项内容

slider_mapping:
0: master
1: 
    - QQ.exe
    - WeChat.exe
    - KOOK.exe
2: deej.unmapped

invert_sliders: false

com_port: COM5 # 此处填写步骤2中你看到的串口号
baud_rate: 9600

noise_reduction: default

双击deej.exe即可开始使用

2024-04-15 该篇文章被 ao 归为分类: Ao科技

前言

需要准备的材料

制作流程